program SV650_ECM_Serial_Hack
'Date: March 14, 2012
'Part: PIC16F1847
'Design: TeeRiver, at SVRider.com
'Ver:1.0
'Use: SV650 Gen2 ECM Serial Stream Emulator

dim ecm_serial_byte as byte[8] '8 bytes, 0 thru 7
dim check_sum as byte
dim index as byte
dim adc_value as word

const dealer_mode = 0
const temp = 0  '0 thru 1023
const C11 = 0 'Undefined for SV650
const C12_CKP = 0
const C13_IAP = 0
const C14_TPS = 0
const C15_ECTS = 0
const C21_IATS = 0
const C22_CAM = 0 'Not used on SV650
const C23_TOS = 0
const C24_IG_Coil_1 = 0
const C25_IG_Coil_2 = 0
const C28_STVA = 0
const C29_STPS = 0
const C31_GPS = 0
const C32_FI_1 = 0
const C33_FI_2 = 0
const C41_FP_Relay = 0
const C42_IG_Switch = 0
const C43 = 0 'Undefined for SV650
const C44 = 0 'Undefined for SV650
const C49_PAIR = 0
const Adj_TPS_0 = 0
const Adj_TPS_1 = 0

'##############################################################################
sub procedure Boot_up()
  'Set internal oscillator
  OSCCON = %01110000 '8MHz
 
  'Set all PIC I/O to DIGITAL, except for ADC1
  ANSELA = %11100010' Configure all 5 PortA AN pins (A4:A0) as DIGITAL I/O
  ANSELB = %00000001' Configure all 7 PortB AN pins (B7:B1) as DIGITAL I/O

  'Set I/O port direction
  TRISB = %11101011 'B4 is test strobe, B2 is UART TX
  TRISA = %11111111

  'Initialize the UART
  UART1_Init(7800)
end sub 'Boot_up

'###############################################################################
main:
  Boot_up()
  'Initialize ECM Data Stream
  for index = 0 to 7
    ecm_serial_byte[index] = $00
  next index
   
  'Assign Error Code bits to data stream
  ecm_serial_byte[1].4 = dealer_mode
  ecm_serial_byte[3].0 = C11 'Undefined for SV650
  ecm_serial_byte[3].1 = C12_CKP
  ecm_serial_byte[3].2 = C13_IAP
  ecm_serial_byte[3].3 = C14_TPS
  ecm_serial_byte[3].4 = C15_ECTS
  ecm_serial_byte[3].5 = C21_IATS
  ecm_serial_byte[3].6 = C22_CAM 'Not used on SV650
  ecm_serial_byte[3].7 = C23_TOS
  ecm_serial_byte[2].0 = C24_IG_Coil_1
  ecm_serial_byte[2].1 = C25_IG_Coil_2
  ecm_serial_byte[4].5 = C28_STVA
  ecm_serial_byte[4].6 = C29_STPS
  ecm_serial_byte[2].2 = C31_GPS
  ecm_serial_byte[2].3 = C32_FI_1
  ecm_serial_byte[2].4 = C33_FI_2
  ecm_serial_byte[2].7 = C41_FP_Relay
  ecm_serial_byte[1].0 = C42_IG_Switch
  ecm_serial_byte[1].5 = C43 'Undefined for SV650
  ecm_serial_byte[4].3 = C44 'Undefined for SV650
  ecm_serial_byte[4].7 = C49_PAIR
  ecm_serial_byte[1].1 = Adj_TPS_0
  ecm_serial_byte[1].2 = Adj_TPS_1
  ecm_serial_byte[0] = temp >> 2
  ecm_serial_byte[1].7 = temp.1
  ecm_serial_byte[1].6 = temp.0
 
  while true
    portb.4 = 1 'Test strobe

   'Read the ECT thermistor
    adc_value = ADC_Read(1)
   
    'Assign thermisor adc voltage to serial data stream
    ecm_serial_byte[0] = adc_value >> 2
    ecm_serial_byte[1].7 = adc_value.1
    ecm_serial_byte[1].6 = adc_value.0

   'Calculate the checksum.
    check_sum = 0
    for index = 0 to 6
      check_sum = check_sum + ecm_serial_byte[index]
    next index
    'Calculate two's compliment
    check_sum = 256 - check_sum

   'Send the datastream
    for index = 0 to 6
      UART1_Write(ecm_serial_byte[index])
      delay_ms(10)
    next index
    UART1_Write(check_sum)
    'Inter-message gap
    delay_ms(30)
    portb.4 = 0
  wend
End.